# Mp3tag (v2.39+) parsing for maniadb, created by dano in 2010-09-16
#
# This *.src file must be placed in your sources directory. 
# On Windows XP it's C:\Documents and Settings\*username*\Application Data\Mp3tag\data\sources
#
# You can quickly reach it with [Windows Key + R] and enter %appdata%\Mp3tag\data\sources
# Or enter %appdata%\Mp3tag\data\sources in the Explorer address bar
#
#    ->  Replace XXXXXXXXXXXXXXXXXXXX with your API key  <-
#

[Name]=maniadb
[BasedOn]=www.maniadb.com
[IndexUrl]=http://www.maniadb.com/api/search.asp?key=XXXXXXXXXXXXXXXXXXXX&target=music&option=album&query=%s
[AlbumUrl]=http://www.maniadb.com/api/album.asp?key=XXXXXXXXXXXXXXXXXXXX&a=
[WordSeperator]=+
[IndexFormat]=%_url%|%_preview%|%Album%|%Year%
[SearchBy]=%album%
[Encoding]=utf-8

[ParserScriptIndex]=...
# ###################################################################
#					I  N  D  E  X
# ###################################################################
debug "on" "c:\debug_maniadb_A.htm" "10"
#debugwriteinput "C:\yDebug\madiadb_A.xml"

findline "<item id=\""
do	
	# Album ID
	findinline "<item id=\""
	sayuntil "\""
	say "|"
	
	# Preview
	say "http://www.maniadb.com/album.asp?a="
	unspace
	findinline "<item id=\""
	sayuntil "\""
	say "|"
	
	# Title
	findline "<title><![CDATA["
	findinline "<title><![CDATA["
	sayuntil "]]>"
	say "|"
	
	# Year
	unspace
	sayregexp "(?<=\()\d\d\d\d(?=\))" ""

	saynewline
	
	findline "</item>"
	moveline 1 1
	unspace
while "<item id=\"" 555
	

[ParserScriptAlbum]=...
# ###################################################################
#					A  L  B  U  M
# ###################################################################
debug "on" "c:\yDebug\debug_maniadb_B.htm" "10"
debugwriteinput "C:\yDebug\madiadb_B.xml"


outputto "Album"
findline "maniadb:shorttitle"
findinline "shorttitle><![CDATA["
sayuntil "]]>"

# Year
outputto "Year"
findline "<releasedate>"
findinline "<releasedate>" 1 1
saynextnumber

# Description
outputto "Comment"
findline "<description><![CDATA["
findinline "<description><![CDATA[" 1 1
sayuntil "]]>"


gotoline 1

findline "maniadb:longtitle" 1 1
findinline " / " 1 1
movechar -3

if " / "
	# VA ########################
	
	# Albumartist
	outputto "ALBUMARTIST"
	findline "maniadb:artist"
	findinline "name><![CDATA["
	sayuntil "]]>"

# Tracks
findline "<song track"
do
	outputto "tracks"
	findline "<title><![CDATA["
	findinline "<title><![CDATA["
	sayuntil "]]>"
	say "|"
	
	moveline 1 1
	outputto "_length"
	sayregexp "(?<=<runningtime>)[^<]+(?=</run)" ""
	say "|"
	
	moveline 1 1
	outputto "Artist"
	findinline "><![CDATA["
	sayuntil "]]>"
	say "|"
	
	findline "<song track" 2 1
while "<song track" 555


	
else # ############################

# Artist
outputto "Artist"
findline "maniadb:artist"
findinline "name><![CDATA["
sayuntil "]]>"


# Tracks
findline "<song track"
do
	outputto "tracks"
	findline "<title><![CDATA["
	findinline "<title><![CDATA["
	sayuntil "]]>"
	say "|"
	
	moveline 1 1
	outputto "_length"
	sayregexp "(?<=<runningtime>)[^<]+(?=</run)" ""
	say "|"
	
	findline "<song track" 2 1
while "<song track" 555


endif # ####################################


# Cover
gotoline 1
findline "<image><![CDATA[" 1 1
unspace
if "<image>"
	outputto "coverurl"
	findinline "<image><![CDATA[" 1 1
	sayuntil "]]>"
endif